Titratiecurven in Excel: sterk zuur met sterke base

Bij de titratie van een zuur met een base is het equivalentiepunt zichtbaar te maken met een indicator. Dat komt omdat in het equivalentiepunt de verandering van de pH zeer groot is. Bij het opnemen van een titratiecurve wordt de pH uitgezet tegen de hoeveelheid toegevoegde base. Met behulp van Excel is het mogelijk een groot aantal titratiecurven te produceren door de variabelen zoals beginvolume en de molariteiten apart in te voeren. Handig bij links-rechts toetsen en bij het bestuderen van titratiecurven.

• Vaardigheden in Excel
• Gegevensvalidatie
• De functies LOG()
• De functie ALS()
• Scheikundige achtergrond
• Het type titratie
• De berekeningen
• Berekeningen bij de titratie van een sterk zuur met sterke base en omgekeerd
• Berekening aantal mL tot het equivalentiepunt
• Sterk zuur met sterke base
• Sterke base met sterk zuur
• Titratiecurven in Excel
• Het werkblad opmaken
• De formules invoeren
• Werkblad mooier maken
• De eerste titratiecurve
• Werken met het werkblad
• Voorbeeld
• Grafiek aanpassen

Vaardigheden in Excel

Bij het maken van grafieken in Excel wordt gebruik gemaakt van een aantal vaardigheden:

• Een reeks getallen invoeren
• Een formule invoeren met verwijzing naar een reeks cellen
• Grafieken invoegen op het werkblad
• Grafieken aanpassen
• Relatieve en absolute verwijzingen

Voor het produceren van titratiecurven komen er bij:

Gegevensvalidatie

Hiermee is voor een cel vast te leggen dat slechts bepaalde waarden kunnen worden ingevoerd. Dit zal worden gebruikt om aan te geven dat het gaat om een zuur-base titratie (0) of een base-zuur titratie (1).

1. Zet de cursor in cel A1, klik op tabblad GEGEVENS en klik bij "hulpmiddelen voor gegevens" op het kleine zwarte pijltje naast gegevensvalidatie.
2. Kies in het menuutje voor gegevensvalidatie en kies bij Instellingen, toestaan voor Geheel getal.
3. Vul bij Minimum 0 in en bij Maximum 1.
4. Klik op het tabblad invoerbericht en type bij titel "Titratie zuur of base" en bij invoerbericht "zuur = 0", [ENTER], "base = 1" (zonder de aanhalingstekens).
5. Sluit af met OK

Als nu in cel A1 een andere waarde dan 0 of 1 wordt ingevoerd, verschijnt het bericht "De waarde die u hebt ingevoerd is ongeldig".

De functies LOG()

Met deze functie berekent Excel de logaritme van een getal. Tussen de haakjes kan een getal, een verwijzing naar een andere cel of een formule met verwijzingen naar andere cellen staan.

De functie ALS()

Deze functie wordt gebruikt om een keuze te maken. In het geval van de titratiecurven gaat het om de keuze voor een formule in zuur milieu of in basisch milieu. Tussen haakjes staat een voorwaarde en wat er moet gebeuren als er wel of niet aan de voorwaarde is voldaan. ALS(A1=0; formule 1) betekent dat als de waarde van cel A1 gelijk is aan 0 dat dan gerekend wordt met formule 1, anders wordt in dit geval de waarde ONWAAR gegeven. De functie ALS() kan ook genest worden. Bijvoorbeeld ALS(A1=0;formule 1;ALS(A1=1;formule 2)) betekent dat als de waarde van A1 0 is, wordt gerekend met formule 1, dat als de waarde van A1 1 is wordt gerekend met formule 2. Gaan geen van beide voorwaarden op dan wordt weer ONWAAR teruggegeven. Geneste ALS() functies worden snel ingewikkeld. Er dient goed gekeken te worden naar de haakjes!

Scheikundige achtergrond

De zuren en basen waarover gesproken wordt, zijn eenwaardig, dat wil zeggen dat per molecuul één H⁺ wordt afgestaan of opgenomen. Bij een zuur-base titratie reageert een zuur HZ met een base B volgens HZ + B → Z^- + HB⁺. Als er precies zoveel B is toegevoegd als nodig is om te reageren met alle HZ is het equivalentiepunt bereikt.

Het type titratie

Er zijn bij titraties met sterke zuren en basen twee mogelijkheden:

• Titratie sterk zuur met sterke base
• Titratie sterke base met sterk zuur

De berekeningen

Er wordt gerekend bij p=p₀ en T=298 K. Bij de berekening van de pH gaat het om drie situaties:

• De pH aan het begin van de titratie
• De pH tijdens het toevoegen van de base (of het zuur) tot het equivalentie punt
• De pH tijdens het toevoegen van de base (of het zuur) na het equivalentiepunt

Berekeningen bij de titratie van een sterk zuur met sterke base en omgekeerd

De reactie is H⁺ + OH^- → H₂O; het equivalentiepunt ligt bij pH = 7.

Berekening aantal mL tot het equivalentiepunt

In het equivalentie punt is het aantal mmol OH^- dat wordt toegevoegd precies gelijk aan het aantal mmol H⁺ dat oorspronkelijk in de oplossing aanwezig was.

• Equivalentiepunt titratie sterk zuur met sterke base: mL(B) = V(HZ)*M(HZ)/M(B)
• Equivalentiepunt titratie sterke base met sterk zuur: mL(HZ) = V(B)*M(B)/M(HZ)

Waarin V staat voor het volume, M voor de molariteit. In de figuur "Berekeningen equivalentiepunt" worden deze formules afgeleid. Klik op de figuur om de afbeelding groter te bekijken.

Sterk zuur met sterke base

V(HZ) is het beginvolume van de zure oplossing, M(HZ) is de molariteit van het zuur, mL(B) is het volume van de hoeveelheid toegevoegde basische oplossing, M(B) is de molariteit van de base waarmee wordt getitreerd.

• Begin pH = -log (M(HZ))
• Tot het equivalentiepunt pH = - log ((V(HZ)*M(HZ) - mL(B)*M(B))/(V(HZ) +mL(B))).
• Na het equivalentiepunt pH = 14 + log ((mL(B)*M(B) - V(HZ)*M(HZ))/(V(HZ) +mL(B))).

In de figuur "Berekeningen sterk zuur met sterke base" worden deze formules afgeleid. Klik op de figuur om de afbeelding groter te bekijken.

Sterke base met sterk zuur

V(B) is het beginvolume van de basische oplossing, M(B) is de molariteit van de base, mL(HZ) is het volume van de hoeveelheid toegevoegde zure oplossing, M(HZ) is de molariteit van het zuur waarmee wordt getitreerd.

• Begin pH = 14 + log M(B)
• Tot het equivalentiepunt pH = - log ((V(B)*M(B) - mL(HZ)*M(HZ))/(V(B) + mL(HZ)))
• Na het equivalentiepunt pH = - log ((mL(HZ)*M(HZ) - V(B)*M(B))/(V(B) + mL(HZ)))

In de figuur "Berekeningen sterke base met sterk zuur" worden deze formules afgeleid. Klik op de figuur om de afbeelding groter te bekijken.

Titratiecurven in Excel

Het werkblad is zo opgebouwd dat de molariteiten en volumes in verschillende cellen worden geplaatst, waarna de titratiecurve wordt geproduceerd. Met behulp van een 0 of een 1 wordt vastgelegd of het gaat om een titratie van een zuur met een base of een base met een zuur.

Het werkblad opmaken

De koppen moeten worden ingevuld zonder de aanhalingstekens.

1. Zet in A1 "Volume(mL)".
2. Zet in B1 "pH".
3. Zet in C1 "totaal volume".
4. Zet in D1 "zuur" en in E1 "base".
5. Zet in G1, H1, I1 en J1 respectievelijk "V(HZ)", "M(HZ)", "V(B)"en "M(B)".
6. Zet in L1 "type titratie".
7. Zet in M1 "equivalentiepunt".
8. Zet in kolom A een reeks waarden van 0 tot en met 50 met een interval van 0,1.
9. Zet in de cellen G2, H2, I2 en J2 respectievelijk 25; 0,1; 25 en 0,1.
10. Zet de cursor in cel L2 en zorg dat de gegevensvalidatie staat op 0 of 1.
11. Type bij gegevensvalidatie, het invoerbericht: de titel "Titratie zuur of base" en het invoerbericht: "zuur = 0"; "base = 1".
12. Zet L2 op 0.

Klik op de figuur om de afbeelding groter te bekijken. De kolommen C, D en E zullen deelresultaten bevatten. Na invoer van de formules kunnen deze kolommen eventueel worden verborgen.

De formules invoeren

Wees heel precies met de haakjes, kopieer de formule eventueel (zonder de aanhalingstekens).

1. Zet in M2 de formule "=ALS(L2=0;G2*H2/J2;ALS(L2=1;I2*J2/H2))"
2. Zet in C2 "=ALS($L$2=0;$G$2+A2;$I$2+A2)"
3. Zet in D2 "=-LOG(H2)"
4. Zet in E2 "=14+LOG(J2)"
5. Kopieer C2 naar beneden tot en met C502
6. Zet in D3 "=ALS(A3<$M$2;-LOG(($G$2*$H$2-A3*$J$2)/C3);ALS(A3=$M$2;7;ALS(A3>$M$2;14+LOG((A3*$J$2-$G$2*$H$2)/C3))))"
7. Zet in E3 "=ALS(A3<$M$2;14+LOG(($I$2*$J$2-A3*$H$2)/C3);ALS(A3=$M$2;7;ALS(A3>$M$2;-LOG((A3*$H$2-$I$2*$J$2)/C3))))"
8. Kopieer D3 en E3 naar beneden tot en met D502 respectievelijk E502
9. Zet in B2 "=ALS($L$2=0;D2;E2)" en kopieer naar beneden tot en met B502

Klik op de figuur om de afbeelding groter te bekijken. In kolom D wordt de pH berekend als een zure oplossing wordt getitreerd met een basische oplossing. In kolom E wordt de pH berekend als een basische oplossing wordt getitreerd met een zure oplossing. Kolom B vermeldt het resultaat uit kolom D of E, afhankelijk van de inhoud van cel L2.

Werkblad mooier maken

1. Verberg kolom C, D en E door de drie kolommen te selecteren, ergens rechts in het geselecteerde gebied te klikken en te kiezen voor verbergen.
2. Selecteer kolom A en B en klik ergens rechts in het geselecteerde gebied. Kies voor Celeigenschappen en zet bij Getal, Getal het aantal decimalen op 2. Kies in Celeigenschappen bij Uitlijning, Horizontaal voor links inspringen.
3. Zet in G2 en I2 het aantal decimalen op 2 en lijn links uit.
4. Zet in H2 en J2 het aantal decimalen op 4 en lijn links uit.
5. Centreer L2.
6. Zet in M2 het aantal decimalen op 2 en lijn links uit.

De eerste titratiecurve

Teken de titratiecurve voor de titratie van 25 mL 0,1011 molair natronloog (NaOH-oplossing) met 0,09973 molair zoutzuur (HCl-oplossing).

1. Geef H2 de waarde 0,09973
2. Geef I2 de waarde 25
3. Geef J2 de waarde 0,1011
4. Zet L2 op 1.
5. Selecteer A1 tot en met B502, scroll terug naar boven en voeg het spreidingsdiagram in.
6. Sla op onder de naam "Titratiecurven sterk - sterk.xlsx"

Titratiecurven sterk - sterk.xlsx kan worden gedownload en geopend in Excel. Het is te gebruiken als uitgangspunt voor het produceren van nieuwe titratiecurven.

Opmerking 1: In de verborgen kolom D staan nu fouten, die genegeerd kunnen worden. In kolom B staan de waarden uit kolom E waarin geen fouten voorkomen; als L2 op 0 wordt gezet, staan de fouten in kolom E. Kolom B bevat dan de waarden van kolom D, waarin geen fouten voorkomen.
Opmerking 2: Als de molariteiten kleiner dan 0,0001 worden gemaakt, gelden bepaalde aannames bij de berekeningen niet meer. De titratiecurve krijgt dan rond het equivalentie punt een rare knik.

Werken met het werkblad

In het werkblad met de eerste titratiecurve kunnen nu allerlei titratiecurven worden geproduceerd, die vervolgens kunnen worden gekopieerd naar een Word-document. Zie maar eens wat er gebeurt als K2 de waarde 0 krijgt.

Voorbeeld

Om de titratiecurve te tekenen voor de titratie van 10,00 mL 0,1141 M zoutzuur met 0,09775 M natronloog is de volgende invoer vereist:

1. G2=10
2. H2=0,1141
3. J2=0,09775
4. L2=0

Grafiek aanpassen

Ga met de cursor over de horizontale as, tot "As horizontaal (waarde)" te zien is. Klik rechts en kies voor "As opmaken". Verander rechts bij "Grenzen" het maximum in 25. Sla dit werkblad eventueel onder een nieuwe naam op.