Titratiecurven in Excel: zwak zuur met sterke base

Titratiecurven geven een goed inzicht in de verandering van de pH tijdens de titratie. Rondom het equivalentiepunt treedt een sterke stijging of daling van de pH op. De keuze van een indicator is afhankelijk van de sterkte van het zuur (bij een zuurbasetitratie) of de sterkte van de base (bij een basezuurtitratie). Of een indicator sowieso bruikbaar is, is tevens afhankelijk van de lengte van het steile stuk in de titratiecurve. Door het tekenen van deze curven in Excel komen die factoren goed in beeld. Bovendien is een werkblad waarmee eenvoudig diverse titratiecurven zijn te produceren ideaal om te gebruiken bij verschillende versies van toetsen.

• Vaardigheden in Excel
• Scheikundige achtergrond
• Het type titratie
• De berekeningen
• Berekeningen bij de titratie van een zwak zuur met OH^-
• Berekening aantal mL loog tot het equivalentiepunt
• Begin pH
• pH in het equivalentiepunt
• pH vóór het equivalentiepunt
• pH na het equivalentiepunt
• Berekeningen bij de titratie van een zwakke base met H⁺
• Berekening aantal mL zuur tot het equivalentiepunt
• Begin pH
• pH in het equivalentiepunt
• pH vóór het equivalentiepunt
• pH na het equivalentiepunt
• Titratiecurven in Excel
• De koppen opmaken
• Het werkblad opmaken
• Uitleg bij het werkblad
• De formules invoeren
• Uitleg bij enkele formules
• Het aantal mL loog dat nodig is om het equivalentiepunt te bereiken
• De pH in het equivalentiepunt
• De pH vóór het equivalentiepunt
• De pH na het equivalentiepunt
• Beperkingen van het werkblad
• Een titratiecurve tekenen
• Werken met het werkblad
• Voorbeeld: titratie ammoniak met zoutzuur
• Grafiek aanpassen

Vaardigheden in Excel

Bij het maken van grafieken in Excel wordt gebruik gemaakt van een aantal algemene vaardigheden:

• Een reeks getallen invoeren
• Een formule invoeren met verwijzing naar een reeks cellen
• Grafieken invoegen op het werkblad
• Grafieken aanpassen
• Relatieve en absolute verwijzingen

Bij het maken van titratiecurven wordt daarnaast gebruik gemaakt van deze specifieke vaardigheden:

• Gegevensvalidatie
• De functies LOG() en WORTEL()
• De functie (ALS)

Scheikundige achtergrond

De omstandigheden zijn p=p₀ en T=298 K.

Het type titratie

Er zijn bij deze titraties twee mogelijkheden:

• Titratie van een zwak eenwaardig zuur met OH^-
• Titratie van een zwakke eenwaardige base met H⁺

De berekeningen

Bij de berekening van de pH gaat het om vier situaties:

• De pH aan het begin van de titratie
• De pH in het equivalentiepunt
• De pH tijdens het toevoegen van OH^- (of H⁺) tot het equivalentiepunt
• De pH tijdens het toevoegen van OH^- (of H⁺) na het equivalentiepunt

Berekeningen bij de titratie van een zwak zuur met OH^-

De reactie is HZ + OH^- → Z^- + H₂O, de pH in het equivalentiepunt ligt boven de 7.

Berekening aantal mL loog tot het equivalentiepunt

In het equivalentiepunt is het aantal mmol OH^- dat is toegevoegd precies gelijk aan het aantal mmol HZ.dat in de oplossing aanwezig was.

• aantal mL equivalentiepunt = V(HZ)*M(HZ)/M(OH^-)

Hierin is V(HZ) het volume van de zure oplossing, M(HZ) de molariteit daarvan en M(OH^-) de molariteit van de basische oplossing die wordt toegevoegd. Klik op de afbeelding om hem te vergroten.

Begin pH

Er is sprake van dit evenwicht HZ ⇄ H⁺ + Z^-.

• pH = -log((-K_z+√(K_z² + 4*K_z*M(HZ)))/2)

Hierin is K_z de zuurconstante van het zwakke zuur HZ.

pH in het equivalentiepunt

In het equivalentiepunt heeft zich het volgende evenwicht ingesteld Z^- + H₂O ⇄ HZ + OH^-. Deze oplossing is dus basisch. Bij de berekening wordt de K_b van de geconjugeerde base van HZ gebruikt.

• pH = 14 + log((-K_b+√(K_b²+4*K_b*[Z^-]))/2)

pH vóór het equivalentiepunt

Er ontstaat een buffermengsel. Eerst stijgt de pH verhoudingsgewijs flink; halverwege het equivalentiepunt is de maximale buffercapaciteit met pH = pK_z.

• pH = -log((-([Z^-]+K_z)+√(([Z^-]+K_z)²+4*K_z*[HZ]))/2)

pH na het equivalentiepunt

De reactie is HZ + OH^- → Z^- + H₂O. Na het equivalentiepunt is er een overmaat OH^- toegevoegd.

• pH = 14 + log[OH^-]

Berekeningen bij de titratie van een zwakke base met H⁺

De reactie is B + H⁺ → HB⁺. De pH in het equivalentiepunt ligt onder de 7.

Berekening aantal mL zuur tot het equivalentiepunt

In het equivalentiepunt is het aantal mmol H⁺ dat is toegevoegd precies gelijk aan het aantal mmol B.dat in de oplossing aanwezig was.

• aantal mL equivalentiepunt = V(B)*M(B)/M(H⁺)

Hierin is V(B) het volume van de basische oplossing, M(B) de molariteit daarvan en M(H⁺) de molariteit van de zure oplossing die wordt toegevoegd. Klik op de afbeelding om hem te vergroten.

Begin pH

Er is sprake van dit evenwicht B + H₂O ⇄ HB⁺ + OH^-

• pH = 14 + log((-K_b+√(K_b² + 4*K_b*M(B)))/2)

Hierin is K_b de baseconstante van de zwakke base B.

pH in het equivalentiepunt

In het equivalentiepunt heeft zich het volgende evenwicht ingesteld HB⁺ ⇄ H⁺ + B. Deze oplossing is dus zuur. Bij de berekening wordt de K_z van het geconjugeerde zuur van B gebruikt.

• pH = -log((-K_z+√(K_z²+4*K_z*[HB⁺]))/2)

pH vóór het equivalentiepunt

Er ontstaat een buffermengsel. Eerst daalt de pH verhoudingsgewijs flink; halverwege het equivalentiepunt is de maximale buffercapaciteit met pH = 14 - pK_b.

• pH = 14+log((-[HB⁺]+K_b)+√(([HB⁺]+K_b)²+4*K_b*[B]))/2)

pH na het equivalentiepunt

De reactie is B + H⁺ → HB⁺. Na het equivalentiepunt is er een overmaat H⁺ toegevoegd.

• pH = -log[H⁺]

Titratiecurven in Excel

Eerst worden de koppen opgemaakt, daarna het deel van het werkblad met de variabelen en de berekeningen.

De koppen opmaken

De koppen moeten worden ingevuld zonder de aanhalingstekens.

1. Zet in A1 "V(mL)
2. Zet in B1 "pH"
3. Zet in C1 "V(totaal)
4. Zet in D1 "zuur"
5. Zet in E1 "base"
6. Zet in G1 "K(zuur/base)"
7. Selecteer G1 en H1 en kies bij "Uitlijning" voor "Samenvoegen en Centreren"
8. Zet in I1 "K(base/zuur)" en voeg I1 samen met J1
9. Zet in L1 "V(HZ)"
10. Zet in M1 "M(HZ)"
11. Zet in N1 "V(B)"
12. Zet in O1 "M(B)"
13. Zet in Q1 "type"
14. Zet in R1 "ep" en voeg R1 samen met S1
15. Zet in T1 "M(ep)" en voeg samen met U1
16. Maak deze koppen vet

Het werkblad opmaken

Op de pH-berekeningen na wordt het werkblad verder ingevuld.

1. Zet in kolom A een reeks waarden van 0 tot en met 50 met een interval van 0,1
2. Zet het aantal decimalen in kolom A op 2
3. Zet in cel G2 "Kz" en in cel G3 "Kb(gec.)"
4. Maak cel H2 en H3 op in de wetenschappelijke notatie (Celeigenschappen, Wetenschappelijk, 2 decimalen)
5. Zet in cel I2 "Kb" en in cel I3 "Kz(gec.)"
6. Maak cel J2 en J3 op in de wetenschappelijke notatie
7. Geef cel H2 en J2 de waarde 1,00.10^-5 door 1E-5 te typen
8. Type in cel H3 "=1E-14/G2" en in cel J3 "=1E-14/J2"
9. Geef cel L2,M2,N2 en O2 respectievelijk de waarden "25", "0,1", "25", "0,1"
10. Zet het aantal decimalen in L2 en N2 op 2 en in M2 en O2 op 4
11. Zet de gegevensvalidatie in cel Q2 op de gehele getallen 0 en 1 en geef het invoerbericht de titel "Kies type titratie"
12. Het invoerbericht is "zuur=0; base=1"
13. Geef cel Q2 de waarde 0
14. Zet in cel R2 "volume"en in cel R3 "pH"
15. Zet in cel T2 "gec. base" en in cel T3 "gec. zuur"

Uitleg bij het werkblad

De formules veranderen met de waarde van Q2 (type titratie).

• Als Q2 op 0 staat, gaat het om de titratie van een zwak zuur met de sterke base OH^-. Na invoer van K_z in H2 wordt de K_b van de geconjugeerde base direct uitgerekend in H3. Nadat de formules zijn ingevoerd staat in S2 hoeveel mL van de hydroxide-houdende oplossing moet worden toegevoegd om het equivalentiepunt te bereiken. In U2 staat de molariteit van de geconjugeerde base in het equivalentiepunt.
• Als Q2 op 1 staat, gaat het om de titratie van een zwakke base met het sterke zuur H⁺. Na invoer van K_b in J2 wordt de K_z van het geconjugeerde zuur direct uitgerekend in J3. Nadat de formules zijn ingevoerd staat in S2 hoeveel mL van de hydronium-houdende oplossing moet worden toegevoegd om het equivalentiepunt te bereiken. In U3 staat de molariteit van het geconjugeerde zuur in het equivalentiepunt.

De formules invoeren

De formules staan tussen aanhalingstekens. Een foutje bij het overtypen is snel gemaakt. Het alternatief is deze formules te kopiëren naar het werkblad.

1. Zet in cel S2 "=ALS(Q2=0;L2*M2/O2;ALS(Q2=1;N2*O2/M2))"
2. Zet in cel U2 "=(L2*M2)/(L2+S2)"
3. Zet in cel U3 "=(N2*O2)/(N2+S2)"
4. Zet in cel S3 "=ALS(Q2=0;14+LOG((-H3+WORTEL(H3*H3+4*U2*H3))/2);-LOG((-J3+WORTEL(J3*J3+4*U3*J3))/2))"
5. Zet in cel C2 "=ALS($Q$2=0;$L$2+A2;$N$2+A2)"
6. Kopieer de inhoud van C2 naar beneden tot en met C502
7. Kopieer in cel D2 "=-LOG((-H2+WORTEL(H2*H2+4*M2*H2))/2)"
8. Kopieer in cel E2 "=14+LOG((-J2+WORTEL(J2*J2+4*O2*J2))/2)"
9. Kopieer in cel D3 "=ALS($Q$2=0;ALS(A3<$S$2;-LOG((-(A3*$O$2/C3+$H$2)+WORTEL((A3*$O$2/C3+$H$2)^2+4*$H$2*($L$2*$M$2-A3*$O$2)/C3))/2);ALS(A3=$S$2;$S$3;14+LOG((A3*$O$2-$L$2*$M$2)/C3))))"
10. Kopieer in cel E3 "=ALS($Q$2=1;ALS(A3<$S$2;14+LOG((-(A3*$M$2/C3+$J$2)+WORTEL((A3*$M$2/C3+$J$2)^2+4*$J$2*($N$2*$O$2-A3*$M$2)/C3))/2);ALS(A3=$S$2;$S$3;-LOG((A3*$M$2-$N$2*$O$2)/C3))))"; besteed geen aandacht aan de inhoud ONWAAR.
11. Kopieer de inhoud van cel D3 respectievelijk E3 naar beneden tot en met D502 en E502
12. Zet in cel B2 "=ALS($Q$2=0;D2;E2)"
13. Kopieer de inhoud van cel B2 naar beneden tot en met B502
14. Zet het aantal decimalen in kolom B, C, D en E op 2
15. Zet het aantal decimalen in S2 en S3 op 2
16. Zet het aantal decimalen in U2 en U3 op 4

Uitleg bij enkele formules

De formules zijn afhankelijk van de waarde van cel Q2. Er wordt eerst gekeken of het een titratie is van een zwak zuur of de titratie van een zwakke base. Daarna wordt gekeken of de toegevoegde hoeveelheid base (of zuur) minder of meer is dan de hoeveelheid om het equivalentiepunt te bereiken (of misschien wel gelijk aan die waarde). De verdere uitleg wordt gegeven voor de titratie van een zwak zuur met OH^-. De molariteit van dit loog staat in O2. (De uitleg bij de titratie van een zwakke base is volkomen vergelijkbaar)

Het aantal mL loog dat nodig is om het equivalentiepunt te bereiken

Het aantal mmol OH^- = het aantal mmol HZ. Dat is V(HZ)*M(HZ), dus L2*M2.
Het aantal ml OH^- = V(HZ)*M(HZ)/M(B).

• Het volume van de toegevoegde base (cel S2) is dus L2*M2/O2

De pH in het equivalentiepunt

Het aantal mmol Z^- = het aantal mmol HZ dat bij het begin in de oplossing aanwezig was,V(HZ)*M(HZ)
Deze hoeveelheid moet gedeeld worden door het volume in het equivalentiepunt om de [Z^-] te berekenen, die in de vergelijking met K_b moet worden gebruikt.

• De molariteit van de geconjugeerde base (cel U2) is dus (L2*M2)/(L2+S2)

De pH vóór het equivalentiepunt

In de vergelijking wordt gerekend met [HZ] en [Z^-] na het toevoegen van de OH^-, maar voordat het evenwicht zich heeft ingesteld. Het aantal mmol HZ dat wordt weggenomen = mL(B)*M(B). Dat moet worden afgetrokken van de oorspronkelijke hoeveelheid: V(HZ)*M(HZ) - ml(B)*M(B) en gedeeld door het totaalvolume.

• Op het werkblad: (L2*M2 - Ax*O2)/Cx (waarin x een geheel getal is waarmee het nummer van de cel wordt aangegeven)

Het aantal mmol Z^- dat wordt gevormd is gelijk aan het aantal mmol OH^- dat heeft gereageerd, ml(B)*M(B). Om de molariteit te berekenen moet gedeeld worden door het totaalvolume.

• Op het werkblad: Ax*O2/Cx

De pH na het equivalentiepunt

Er wordt gerekend met de [OH^-] als al het zuur heeft gereageerd. Het aantal mmol zuur = V(HZ)*M(HZ). Het aantal mmol OH^- dat is toegevoegd = mL(B)*M(B). Er is dus over mL(B)*M(B) - V(HZ)*M(HZ). Voor de berekening van [OH^- ]moet nog gedeeld worden door het totaalvolume.

• Op het werkblad: (Ax*O2-L2*M2)/Cx

Beperkingen van het werkblad

Bij de berekeningen is geen rekening gehouden met het waterevenwicht (behalve dan pH + pOH = 14). Als de oplossingen te verdund zijn en/of de zuren respectievelijk basen te zwak dan dient dat wel te gebeuren. Anders gaat het met name bij de berekeningen rond het equivalentiepunt mis. Er ontstaat dan een kronkel in het steile stuk. Bij concentraties boven 0,005 mol/L en/of K-waarden die niet kleiner zijn dan 5.10^-9 gaat het goed.

Een titratiecurve tekenen

Teken de titratiecurve voor de titratie van 25,00 mL 0,09965 molair azijnzuur met 0,1003 molair natronloog. De Kz van azijnzuur is 1,8.10^-5.

1. Geef cel H2 de waarde "1,8.10^-5" (voer in 1,8E-5)
2. Geef de cellen L2,M2 en O2 respectievelijk de waarden "25,00", 0,09965 en 0,1003
3. Zorg dat Q2 op 0 staat
4. Selecteer de cellen A1 tot en met B502 en scroll terug naar boven
5. Voeg de grafiek in (Invoegen, Grafieken, Spreidings-(X,Y) of bellendiagram, Spreiding met vloeiende lijnen)
6. Verberg de kolommen C, D en E (door ze te selecteren en rechts te klikken in het geselecteerde gebied en te kiezen voor Verbergen)
7. Sla het werkblad op als "titratiecurven zwakke zuren en basen.xlsx"

Werken met het werkblad

Het document Titratiecurven zwakke zuren en basen.xlsx kan worden gedownload en geopend in Excel. Met dit werkblad als uitgangspunt wordt nu een nieuwe titratiecurve gemaakt.

Voorbeeld: titratie ammoniak met zoutzuur

Voor het tekenen van de titratiecurve voor de titratie van 10,00 mL 0,1012 M NH₃ (K_b=1,8.10^-5) met 0,09775 M zoutzuur is de volgende invoer vereist:
Q2=1
N2=10
M2=0,09775
J2=1,8.10^-5

Grafiek aanpassen

1. Ga met de cursor over de horizontale as, tot "As horizontaal (waarde)" te zien is.
2. Klik rechts en kies voor "As opmaken".
3. Verander rechts bij "Grenzen" het maximum in 25.